[orx-expression-evaluator] Switch to antlr-kotlin for parser generation and make it a common kotlin module

orx-expression-evaluator/src/commonMain/antlr/KeyLangLexer.g4

@@ -0,0 +1,52 @@
+lexer grammar KeyLangLexer;
+
+channels { WHITESPACE }
+
+// Whitespace
+NEWLINE            : '\r\n' | '\r' | '\n' ;
+WS                 : [\t ]+ -> channel(WHITESPACE) ;
+
+// Keywords
+INPUT              : 'input' ;
+VAR                : 'var' ;
+PRINT              : 'print';
+AS                 : 'as';
+INT                : 'Int';
+DECIMAL            : 'Decimal';
+STRING             : 'String';
+
+// Identifiers
+ID                 : [$_]*[a-zA-Z][A-Za-z0-9_]* | '`'[$_]*[A-Za-z0-9_-]*'`';
+FUNCTION_ID        : [$_]*[a-z][A-Za-z0-9_]* ;
+
+// Literals
+
+DECLIT             : [0-9][0-9]* '.' [0-9]+ ;
+INTLIT             : '0'|[0-9][0-9]* ;
+
+// Operators
+PLUS               : '+' ;
+PERCENTAGE         : '%' ;
+MINUS              : '-' ;
+ASTERISK           : '*' ;
+DIVISION           : '/' ;
+ASSIGN             : '=' ;
+LPAREN             : '(' ;
+RPAREN             : ')' ;
+
+
+COMMA              : ',' ;
+
+STRING_OPEN        : '"' -> pushMode(MODE_IN_STRING);
+
+UNMATCHED          : . ;
+
+mode MODE_IN_STRING;
+
+ESCAPE_STRING_DELIMITER : '\\"' ;
+ESCAPE_SLASH            : '\\\\' ;
+ESCAPE_NEWLINE          : '\\n' ;
+ESCAPE_SHARP            : '\\#' ;
+STRING_CLOSE            : '"' -> popMode ;
+STRING_CONTENT          : ~["\n\r\t\\#]+ ;
+

orx-expression-evaluator/src/commonMain/antlr/KeyLangParser.g4

@@ -0,0 +1,42 @@
+
+parser grammar KeyLangParser;
+
+options { tokenVocab=KeyLangLexer; }
+
+keyLangFile : lines=line+ ;
+
+line      : statement (NEWLINE | EOF) ;
+
+statement : inputDeclaration # inputDeclarationStatement
+          | varDeclaration   # varDeclarationStatement
+          | assignment       # assignmentStatement
+          | print            # printStatement
+          | expression       # expressionStatement ;
+
+print : PRINT LPAREN expression RPAREN ;
+
+inputDeclaration : INPUT type name=ID ;
+
+varDeclaration : VAR assignment ;
+
+assignment : ID ASSIGN expression ;
+
+expression : INTLIT                                                        # intLiteral
+           | DECLIT                                                        # decimalLiteral
+           | ID LPAREN RPAREN                                              # functionCall0Expression
+           | ID LPAREN expression RPAREN                                   # functionCall1Expression
+           | ID LPAREN expression COMMA expression RPAREN                  # functionCall2Expression
+           | ID LPAREN expression COMMA expression COMMA expression RPAREN # functionCall3Expression
+           | ID LPAREN expression COMMA expression COMMA expression COMMA expression RPAREN # functionCall4Expression
+           | ID LPAREN expression COMMA expression COMMA expression COMMA expression COMMA expression RPAREN # functionCall5Expression
+           | ID                                                            # valueReference
+           | LPAREN expression RPAREN                                      # parenExpression
+           | MINUS expression                                              # minusExpression
+           | expression operator=(DIVISION|ASTERISK|PERCENTAGE) expression # binaryOperation1
+           | expression operator=(PLUS|MINUS) expression        # binaryOperation2;
+
+type : DECIMAL # decimal
+     | INT     # integer
+     | STRING  # string ;
+
+